# $Id$
# Maintainer: David C. Rankin <drankinatty@gmail.com>
#
# All modifications and uses of this file are licensed under
# the software for which this file was made for, should the software
# be under an Open Source License, at least version 1.9, defined
# by the Open Source Initiative. In other cases, this file is automatically
# released to the Public Domain.
#

pkgbase=trinity
pkgname=trinity-arts
pkgver=1236201
pkgrel=1
arch=('i686' 'x86_64')
url='http://www.kde.org'
license=('GPL')
groups=('trinity')
pkgdesc="Trinity - arts"
depends=('audiofile'
        'alsa-lib'
        'libmad'
	'libvorbis'
	'trinity-tqtinterface')
makedepends=('pkgconfig' 'cmake' 'autoconf')
provides=('trinity-arts')
conflicts=('trinity-arts')
replaces=('trinity-arts')
options=('libtool' '!strip')
source=()

_svnmod=arts
_svntrunk="svn://anonsvn.kde.org/home/kde/branches/trinity/dependencies/${_svnmod}"

# set Qt location (not needed if profile.d/q3.sh present, set prefix (not used)
_qtdir=/opt/qt
_prefix=${_qtdir}

build() {

  cd ${srcdir}

  msg "Connecting to SVN server to update or checkout ${_svnmod}...."
  if [ -d ${_svnmod}/.svn ]; then
    (cd ${_svnmod} && svn up)
    [[ $? -eq 0 ]] || _co_failed=1
  else
    (svn co $_svntrunk ${_svnmod})
    [[ $? -eq 0 ]] || _co_failed=1
  fi

  cd ${srcdir}/${_svnmod}

  # if update or checkout failed - bail...
  if [[ $_co_failed -ne 1 ]]; then
    msg "SVN checkout of revision $pkgver -- Complete."
  else
    msg "SVN checkout of revision $pkgver -- Failed or server timeout."
    exit 1
  fi

#   cd ${srcdir}/${_svnmod}

  msg "Setting PATH, CMAKE and Trinity Environment variables"
  if [[ -r /etc/profile.d/qt3.sh ]]; then
    . /etc/profile.d/qt3.sh
    [[ -n $QTDIR ]] && _qtdir=$QTDIR
  else
    [[ ${PATH%%:*} =~ ${_qtdir}/bin ]] || export PATH=${_qtdir}/bin:$PATH
  fi

  # exports not required with /opt/qt/include in the right place
#   export CMAKE_PREFIX_PATH=$QTDIR
#   export CMAKE_INCLUDE_PATH=/opt/qt/include:/opt/qt/include/tqt

  trinity_prefix="/opt/trinity"

  cd $srcdir
  msg "Creating out-of-source build directory: ${srcdir}/build"
  mkdir -p build
  cd build

  msg "Starting cmake..."
  cmake ${srcdir}/${_svnmod} \
    -DCMAKE_INSTALL_PREFIX=${trinity_prefix} \
    -DQT_VERSION=3 || return 1

#     -DQT_VERSION=3 \
#     -DWITH_QT3=ON \
#     -DQT_LIBRARY_DIRS=/opt/qt/lib

  make VERBOSE=1

}

package() {
  msg "Packaging - $pkgname-$pkgver"

#   cd ${srcdir}/${_svnmod}
  cd ${srcdir}/build

  make DESTDIR="$pkgdir/" install

#   rm -r ${srcdir}/${_svnmod}
}