# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tdeartwork
pkgver=14.0.10
pkgrel=1
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdeartwork'
license=('GPL')
groups=('tde-base')
pkgdesc="Trinity Desktop Development Ingegration Components - TDE upstream GIT"
depends=('tde-tdebase' 'xscreensaver' 'libxss')
makedepends=('pkgconfig' 'cmake')
optdepends=()
provides=('tdeartwork')
conflicts=('trinity-tdeartwork' 'trinity-kdeartwork')
replaces=('trinity-tdeartwork')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdeartwork-trinity-${pkgver}.tar.xz")
md5sums=('71830a98f9d130a37ba1b3c6107fdd66')
# install=''

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
  cd $srcdir
  msg "Creating out-of-source build directory: ${srcdir}/build"
  mkdir -p build
  cd build

  export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

  msg "Starting cmake..."
  cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
    -DCMAKE_VERBOSE_MAKEFILE=ON \
    -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
    -DWITH_ARTS=ON \
    -DBUILD_ALL=ON

  msg "Building - ${pkgname#*-}..."
  make $NUMJOBS
}

package() {
  msg "Packaging - $pkgname-$pkgver"
  cd ${srcdir}/build
  make -j1 DESTDIR="${pkgdir}" install
}