# Contributor: e1z0 <justinas at eofnet dot lt>

pkgname=tde-tdewebdev
pkgver=14.0.10
pkgrel=1
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdewebdev'
license=('GPL')
groups=('tde-devel')
pkgdesc="Trinity Web Developer Tools"
depends=('tde-tdelibs')
makedepends=('pkgconfig' 'cmake')
provides=('tdewebdev')
conflicts=('trinity-tdewebdev' 'trinity-kdewebdev')
replaces=('trinity-tdewebdev')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdewebdev-trinity-${pkgver}.tar.xz")
md5sums=('96bcdfdcd4308b0721ed23d7d5b9954f')
# install=''

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
      -DCMAKE_VERBOSE_MAKEFILE=ON \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR \
      -DBUILD_ALL=ON

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}