# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

_mod=basket
_cat=applications/office/
_kdemod="${_mod/tde/kde}"

pkgname="tde-${_mod}"
pkgver=14.0.11
pkgrel=1
pkgdesc="A multi-purpose note-taking application for KDE"
arch=('i686' 'x86_64')
url="https://scm.trinitydesktop.org/scm/git/${_mod}"
license=('GPL')
provides=("${_mod}")
groups=('tde-complete')
depends=(
  'tde-tdelibs'
)
makedepends=(
  'tde-cmake-trinity'
  'tde-tdepim'
)
optdepends=()
conflicts=("trinity-${_mod}" "kdemod3-${_kdemod}")
replaces=("trinity-${_mod}")
options=('staticlibs' 'libtool' '!strip')
install=

source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/${_cat}${_mod}-trinity-${pkgver}.tar.xz"
        'bp000-fix-crash-on-export-basket-archive.diff')
md5sums=('1b078e8c8d67c2ce110080fa687bd5cb'
         '402c273bb65646cf377ff9d1be762f07')

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity
[ -n "$QTDIR" ] || QTDIR=${TDEDIR}/tqt3

prepare() {
  cd ${srcdir}/${_mod}-trinity-${pkgver}
  patch -p1 <${srcdir}/bp000-fix-crash-on-export-basket-archive.diff
}

build() {
  msg "Creating out-of-source build directory: ${srcdir}/build"
  mkdir -p "$srcdir/build"
  cd "$srcdir/build"

  export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

  msg "Starting cmake..."
  cmake ${srcdir}/${_mod}-trinity-${pkgver} \
    -GNinja \
    -DCMAKE_VERBOSE_MAKEFILE=ON \
    -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
    -DSYSCONF_INSTALL_DIR=${TDEDIR}/etc \
    -DBUILD_ALL=ON \
    -DWITH_ALL_OPTIONS=ON

  msg "Building - ${pkgname}..."
  ninja $NUMJOBS
}

package() {
  msg "Packaging - ${pkgname}-${pkgver}"
  cd "$srcdir/build"
  DESTDIR="$pkgdir" ninja -j1 install
}