# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tdemultimedia
pkgver=14.0.10
pkgrel=1
pkgdesc="Trinity Desktop MultiMedia Components"
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdemultimedia'
license=('GPL')
groups=('tde-extra')
depends=('tde-tdelibs' 'cdparanoia' 'lame' 'libtheora' 'taglib' 'xine-lib')
makedepends=('pkgconfig' 'cmake')
provides=('tdemultimedia')
conflicts=('trinity-tdemultimedia' 'trinity-kdemultimedia')
replaces=('trinity-tdemultimedia')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdemultimedia-trinity-${pkgver}.tar.xz")
md5sums=('f1f40920c9eed566eaa98a81b838b7b8')
# install=''

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
      -DCMAKE_VERBOSE_MAKEFILE=ON \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR \
      -DWITH_ALL_OPTIONS=ON \
      -DWITH_ARTS_AKODE=OFF \
      -DBUILD_ALL=ON \
      -DBUILD_JUK=OFF

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}