# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tdenetwork
pkgver=14.0.10
pkgrel=1
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdenetwork'
license=('GPL')
groups=('tde-extra')
pkgdesc="Trinity Desktop Network Components"
depends=('tde-tdebase' 'speex' 'wireless_tools' 'wpa_supplicant')
makedepends=('pkgconfig' 'cmake')
provides=('tdenetwork')
conflicts=('trinity-tdenetwork' 'trinity-kdenetwork')
replaces=('trinity-tdenetwork')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdenetwork-trinity-${pkgver}.tar.xz")
md5sums=('c3d26523623fbcc65993a044bd83d0f6')
# install=''

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   export PKG_CONFIG_PATH=${TDEDIR}/lib/pkgconfig:${PKG_CONFIG_PATH}

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
      -DCMAKE_VERBOSE_MAKEFILE=ON \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR \
      -DWITH_SPEEX=ON \
      -DWITH_ARTS=ON \
      -DBUILD_ALL=ON

   msg "Building - ${pkgname#*-}..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}