# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tdepim
pkgver=14.0.10
pkgrel=1
pkgdesc="Trinity Desktop PIM Components"
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdepim'
license=('GPL')
groups=('tde-extra')
depends=('tde-tdenetwork' 'boost' 'boost-libs' 'gnokii' 'libxss' 'xscreensaver' 'tde-libcaldav' 'tde-libcarddav')
makedepends=('pkgconfig' 'cmake' )
provides=('tdepim')
replaces=('trinity-tdepim')
options=('staticlibs' 'libtool' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdepim-trinity-${pkgver}.tar.xz")
md5sums=('894562acd7c895da37d8af30b4f1fc61')

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
  cd $srcdir

  msg "Creating out-of-source build directory: ${srcdir}/build"
  mkdir -p build
  cd build

  msg "Starting cmake..."
  cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver} \
    -DCMAKE_C_FLAGS="-fpermissive" \
    -DCMAKE_CXX_FLAGS="-fpermissive" \
    -DCMAKE_VERBOSE_MAKEFILE=ON \
    -DCMAKE_INSTALL_PREFIX=$TDEDIR \
    -DWITH_ALL_OPTIONS=ON \
    -DBUILD_ALL=ON

  msg "Building - ${pkgname#*-}..."
  make $NUMJOBS
}

package() {
  msg "Packaging - $pkgname-$pkgver"
  cd ${srcdir}/build
  make -j1 DESTDIR="${pkgdir}" install
  # Removing /opt/trinity/share/icons/default.tde to prevent a conflict
  rm -rf ${pkgdir}/opt/trinity/share/icons/default.tde
}