#################################################
#
#  (C) 2011 Timothy Pearson
#  kb9vqf (AT) pearsoncomputing.net
#
#  Improvements and feedback are welcome
#
#  This file is released under GPL >= 2
#
#################################################


##### set project version ########################

include( TDEVersion )
cmake_minimum_required( VERSION ${TDE_CMAKE_MINIMUM_VERSION} )
tde_set_project_version( )


##### general package setup #####################

project( tdesvn )


##### include essential cmake modules ###########

include( CheckCXXSourceCompiles )
include( CheckFunctionExists )
include( CheckIncludeFileCXX )
include( CheckLibraryExists )
include( CheckStructHasMember )
include( CheckSymbolExists )
include( CheckTypeSize )
include( FindPkgConfig )


##### include our cmake modules #################

include( TDEMacros )


##### setup install paths #######################

include( TDESetupPaths )
tde_setup_paths( )


##### user requested modules ####################

option( BUILD_ALL "Build all" OFF )
option( BUILD_DOC "Build doc" ${BUILD_ALL} )
option( BUILD_TRANSLATIONS "Build translations" ${BUILD_ALL} )
option( BUILD_TESTS "Building the tests yes or no (default off)" OFF)


##### testing ###################################

set(TESTINGBUILD OFF CACHE BOOL "Enable/Disable special testing flags")
if (TESTINGBUILD)
   add_definitions("-DTESTING_RC=\"\\\"\${CMAKE_SOURCE_DIR}/src/tdesvnui.rc\\\"\" -DTESTING_PARTRC=\"\\\"\${CMAKE_SOURCE_DIR}/src/tdesvn_part.rc\\\"\"")
   add_definitions("-DFORCE_ASKPASS=\"\\\"\${CMAKE_BINARY_DIR}/bin/tdesvnaskpass\\\"\"")
endif (TESTINGBUILD)

if(BUILD_TESTS)
  enable_testing()
endif(BUILD_TESTS)


##### versioning ################################

set(BASE_VERSION 1.0.4)
set(KDESVN_VERSION "$ENV{KDESVN_VERSION}")
if(NOT KDESVN_VERSION)
	set(KDESVN_VERSION ${BASE_VERSION})
endif(NOT KDESVN_VERSION)


##### configure checks ##########################

include( ConfigureChecks.cmake )


###### global compiler settings #################

add_definitions(
  -DHAVE_CONFIG_H
)

set( CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${TQT_CXX_FLAGS}" )
set( CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} -Wl,--no-undefined" )
set( CMAKE_MODULE_LINKER_FLAGS "${CMAKE_MODULE_LINKER_FLAGS} -Wl,--no-undefined" )


##### source directories ########################

add_subdirectory( src )
tde_conditional_add_project_docs( BUILD_DOC )
tde_conditional_add_project_translations( BUILD_TRANSLATIONS )


##### write configure files #####################

configure_file( config.h.cmake config.h @ONLY )
configure_file( tdesvn-config.h.in tdesvn-config.h @ONLY )