# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: Pawel 'l0ner' Soltys <pwslts@gmail.com>
# Contributor: Calvin Morrison <mutantturkey@gmail.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-dbus-tqt
pkgver=14.0.5
pkgrel=1
arch=('i686' 'x86_64')
url='http://scm.trinitydesktop.org/scm/git/dbus-tqt'
license=('GPL')
groups=('tde-core')
pkgdesc="Trinity TQt DBus wrapper"
depends=('tde-arts' 'dbus')
makedepends=('pkgconfig' 'cmake')
provides=('dbus-tqt')
options=('staticlibs' 'libtool' '!strip')
source=("http://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/dependencies/dbus-tqt-R${pkgver}.tar.bz2")
md5sums=('619e65a35e2e750900f1d10931b6698c')
install='trinity-dbus-tqt.install'

build() {
   cd $srcdir
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p build
   cd build

   msg "Starting cmake..."
   cmake ${srcdir}/dependencies/${pkgname#*-} \
      -DCMAKE_INSTALL_PREFIX=$TDEDIR

   msg "Building - $pkgname..."
   make $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   make -j1 DESTDIR="${pkgdir}" install
}