summaryrefslogtreecommitdiffstats
path: root/arch/tde-core/tde-arts/PKGBUILD
blob: a546c02dcf9c0090189c29579b917e0cc28a4b42 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: Pawel 'l0ner' Soltys <pwslts@gmail.com>
# Contributor: Calvin Morrison <mutantturkey@gmail.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

_mod=arts
_cat=dependencies/
_kdemod="${_mod/tde/kde}"

pkgname="tde-${_mod}"
pkgver=14.0.12
pkgrel=1
pkgdesc="Trinity aRts Sound System and libraries"
arch=('i686' 'x86_64')
url="https://scm.trinitydesktop.org/scm/git/${_mod}"
license=('GPL')
groups=('tde-core')
depends=('alsa-plugins'
	'alsa-tools'
	'alsa-utils'
	'audiofile'
	'glib2'
	'libmad'
	'libogg'
	'libvorbis'
	'pulseaudio-alsa'
	'tde-tqtinterface')
makedepends=('tde-cmake-trinity')
optdepends=('audio-convert: A script with an easy to use interface to convert audio files: wav, mp3, ogg, flac, aac, mpc, ape and wma'
	'lame: A high quality MPEG Audio Layer III (MP3) encoder'
	'libmp3splt: Library for splitting mp3 and ogg files without decoding'
	'mpd: Music daemon that plays MP3, FLAC, and Ogg Vorbis files'
	'vorbis-tools: Extra tools for Ogg-Vorbis')
provides=("${_mod}")
conflicts=("kdemod3-${_mod}" "${_mod}")
replaces=("trinity-${_mod}")
options=('staticlibs' 'libtool' '!emptydirs')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/${_cat}${_mod}-trinity-${pkgver}.tar.xz")
md5sums=('a48103a0a8ecdc098f6f2f834f0951cb')
install="tde-${_mod}.install"

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
   msg "Creating out-of-source build directory: ${srcdir}/build"
   mkdir -p ${srcdir}/build
   cd ${srcdir}/build

   msg "Starting cmake..."
   cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver}/ \
      -GNinja \
      -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
      -DWITH_ALL_OPTIONS=ON \
      -DWITH_ESOUND=OFF \
      -DWITH_JACK=OFF

   msg "Building $pkgname..."
   ninja $NUMJOBS
}

package() {
   msg "Packaging - $pkgname-$pkgver"
   cd ${srcdir}/build
   DESTDIR="$pkgdir" ninja -j1 install
}