summaryrefslogtreecommitdiffstats
path: root/arch/tde-core/tde-tdelibs/PKGBUILD
blob: 8d645b8e980e70c2fbf975fdf26f021c429d8fb5 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
# Maintainer: Michael Manley <mmanley@nasutek.com>
# Contributor: Pawel 'l0ner' Soltys <pwslts@gmail.com>
# Contributor: Calvin Morrison <mutantturkey@gmail.com>
# Contributor: David C. Rankin <drankinatty at gmail dot com>

pkgname=tde-tdelibs
pkgver=14.0.10
pkgrel=1
pkgdesc="Trinity Desktop core libraries and applications"
arch=('i686' 'x86_64')
url='https://scm.trinitydesktop.org/scm/git/tdelibs'
license=('GPL')
groups=('tde-core')
depends=('aspell'
	'hspell'
	'jasper'
	'libcups'
	'libidn'
	'libutempter'
	'libxcomposite'
	'libxslt'
	'libxtst'
	'openssl-1.0'
	'openexr'
	'pcre'
	'tde-arts'
	'tde-avahi-tqt'
	'tde-dbus-1-tqt'
	'tde-libart-lgpl'
	'xorg-iceauth'
	'xorg-xmessage'
	'xorg-xprop'
	'xorg-xset'
	'xorg-xsetroot')
makedepends=('pkgconfig' 'cmake')
provides=('tdelibs')
conflicts=('trinity-kdelibs' 'trinity-tdelibs' 'kdemod3-kdelibs' 'kdelibs3')
replaces=('trinity-kdelibs' 'trinity-tdelibs')
options=('staticlibs' 'libtool' '!makeflags' '!strip')
source=("https://mirror.ppa.trinitydesktop.org/trinity/releases/R${pkgver}/main/core/tdelibs-trinity-${pkgver}.tar.xz")

md5sums=('cbb77407a886b588b4749524ae8e5edd')

install='trinity-tdelibs.install'

[ -n "$TDEDIR" ] || TDEDIR=/opt/trinity

build() {
  cd $srcdir
  msg "Creating out-of-source build directory: ${srcdir}/build"
  mkdir -p build
  cd build

  export PKG_CONFIG_PATH=/usr/lib/openssl-1.0/pkgconfig

  msg "Starting cmake..."
  cmake ${srcdir}/${pkgname#*-}-trinity-${pkgver}/ \
    -DCMAKE_INSTALL_PREFIX=${TDEDIR} \
    -DSYSCONF_INSTALL_DIR=${TDEDIR}/etc \
    -DCMAKE_VERBOSE_MAKEFILE=ON \
    -DWITH_ARTS=ON \
    -DWITH_ALSA=ON \
    -DWITH_LIBART=ON \
    -DWITH_LIBIDN=ON \
    -DWITH_SSL=ON \
    -DWITH_CUPS=ON \
    -DWITH_LUA=OFF \
    -DWITH_TIFF=ON \
    -DWITH_JASPER=ON \
    -DWITH_OPENEXR=ON \
    -DWITH_UTEMPTER=ON \
    -DWITH_AVAHI=ON \
    -DWITH_PAM=ON \
    -DWITH_PCRE=ON \
    -DWITH_GCC_VISIBILITY=ON \
    -DWITH_TDEHWLIB_DAEMONS=ON \
    -DWITH_UPOWER=ON \
    -DWITH_UDISKS2=ON \
    -DWITH_LZMA=ON \
    -DWITH_XRANDR=ON \
    -DWITH_XCOMPOSITE=ON \
    -DWITH_ASPELL=ON \
    -DWITH_HSPELL=ON

  msg "Building - $pkgname..."
  make $NUMJOBS
}

package() {
  msg "Packaging - $pkgname-$pkgver"
  cd ${srcdir}/build
  make -j1 DESTDIR="$pkgdir" install
  msg "Removing conflicting images"
  rm ${pkgdir}/opt/trinity/share/mimelnk/application/x-mplayer2.desktop
}