summaryrefslogtreecommitdiffstats
path: root/arch/tde-deps/libxml++2.6/PKGBUILD
blob: 56686585b98b5112273dca62572a326f360c4b4d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
# Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
# Contributor: damir <damir@archlinux.org>

pkgbase=libxml++2.6
pkgname=(libxml++2.6 libxml++2.6-docs)
pkgver=2.42.1
pkgrel=1
pkgdesc="C++ bindings to libxml2"
url="https://libxmlplusplus.github.io/libxmlplusplus/"
arch=('powerpc64le')
license=(LGPL)
depends=(libxml2 glibmm)
makedepends=(git meson mm-common glibmm-docs)
options=(!emptydirs)
_commit=ceedcb1ca7462305cbca16464bbc5ea50d89c356  # tags/2.42.1^0
source=("git+https://github.com/libxmlplusplus/libxmlplusplus#commit=$_commit")
sha256sums=('SKIP')

pkgver() {
  cd libxmlplusplus
  git describe --tags | sed 's/-/+/g'
}

prepare() {
  cd libxmlplusplus
}

build() {
  arch-meson libxmlplusplus build -D maintainer-mode=true
  meson compile -C build
}

check() {
  meson test -C build --print-errorlogs
}

package_libxml++2.6() {
  provides=("libxml++2=$pkgver" libxml++-2.6.so)
  conflicts=(libxml++2)
  replaces=(libxml++2)

  meson install -C build --destdir "$pkgdir"

  # Split -docs
  mkdir -p docs/usr/share
  mv -t docs/usr/share "$pkgdir"/usr/share/{devhelp,doc}
}

package_libxml++2.6-docs() {
  pkgdesc+=" (documentation)"
  depends=()
  options=(!strip)

  mv -t "$pkgdir" docs/*
}