summaryrefslogtreecommitdiffstats
path: root/configure.in.in
blob: cd92d3cb20e5e5431bea7002e750a42c15dc6c51 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
#MIN_CONFIG(3.3)
AC_HEADER_DIRENT
AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h sys/sysctl.h sys/param.h sys/time.h sys/types.h unistd.h values.h sys/limits.h err.h sys/cdefs.h)

AC_CHECK_SETENV
AC_CHECK_UNSETENV

KDE_NEED_FLEX

if test "$x_includes" != "NONE"; then
  AC_DEFINE(HAVE_X11_HEADERS,1,Define if you have X11 header files)
fi
AC_CHECK_LIB(Xtst, XTestFakeKeyEvent, [LIBXTST=-lXtst],, -lX11)
AC_SUBST(LIBXTST)
if test "$LIBXTST" != ""; then
  AC_CHECK_HEADER([X11/extensions/XTest.h],
                  [AC_DEFINE(HAVE_XTEST, 1, [Define if you have X11 Xtest header files])])
fi

KDE_INIT_DOXYGEN([KDE PIM API Reference], [Version $VERSION])

KDE_CHECK_THREADING

dnl For apps that NEED threads
if test -z "$LIBPTHREAD" && test -z "$USE_THREADS"; then
  DO_NOT_COMPILE="$DO_NOT_COMPILE knode"
fi

CXXFLAGS="$CXXFLAGS $KDE_DEFAULT_CXXFLAGS"

# check for libbluetooth (Bluetooth library) because gnokii may require it
AC_DEFUN([KDE_CHECK_BLUETOOTH],
[
  AC_CHECK_HEADERS(bluetooth/bluetooth.h)
  LIB_BLUETOOTH=
  AC_CHECK_LIB(bluetooth, hci_open_dev,
       [ LIB_BLUETOOTH="-lbluetooth" ],
       [],
       [] )
  AC_SUBST(LIB_BLUETOOTH)
])


# check for libgnokii (Nokia mobile phone library)
AC_DEFUN([KDE_CHECK_GNOKII],
[
  KDE_CHECK_HEADERS(gnokii.h)
  AC_REQUIRE([AC_HAVE_XPM])
  AC_CHECK_LIB(gnokii, gn_cfg_read,
       [ LIB_GNOKII="-lgnokii $LIB_BLUETOOTH" ],
       [
    	AC_CHECK_LIB(gnokii, gn_cfg_get,
       	[ LIB_GNOKII="-lgnokii -lintl $LIB_BLUETOOTH" ],
       	[], $all_libraries -lintl -lXpm -lX11 $LIB_BLUETOOTH )
       ],
       $all_libraries -lXpm -lX11 $LIB_BLUETOOTH )
  AC_SUBST(LIB_GNOKII)
])

AC_ARG_WITH(gnokii,
  [AC_HELP_STRING(--with-gnokii,
    [enable support for mobile phones through gnokii @<:@default=check@:>@])],
  [], with_gnokii=check)

LIB_GNOKII=
if test "x$with_gnokii" != xno; then
  # for kaddressbook/xxport/ and kmobile/devices/gnokii/
  KDE_CHECK_BLUETOOTH
  KDE_CHECK_GNOKII

  if test "x$with_gnokii" != xcheck && test -z "$LIB_GNOKII"; then
    AC_MSG_ERROR([--with-gnokii was given, but test for gnokii failed])
  fi
fi

dnl Checks for header files.
AC_CHECK_HEADERS(sys/cdefs.h) dnl for libkholidays/lunarphase.cpp
AC_CHECK_HEADERS(sys/ioctl.h) dnl for kandy/src/modem.cpp
AC_CHECK_HEADERS(sys/file.h sys/stat.h sys/time.h byteswap.h) dnl for at least kmail

dnl the below is copied from kdenetwork's configure as too many apps moved
dnl and noone can say which tests are needed and which are obsolete for kdepim ;(

AC_CHECK_HEADERS(fcntl.h unistd.h sysent.h strings.h paths.h)

dnl unused AC_CHECK_HEADER([resolv.h],,,[#include <netinet/in.h>])

KDE_CHECK_LARGEFILE

AC_CHECK_USLEEP

dnl Checks for library functions.
AC_CHECK_FUNCS(socket fabsl strdup vsnprintf tzset)
AC_CHECK_GETDOMAINNAME
AC_CHECK_GETHOSTNAME
AC_C_BIGENDIAN

AC_CHECK_RES_INIT

dnl needed by libkmime
AC_CACHE_CHECK(for timezone variable, ac_cv_var_timezone,
	AC_TRY_COMPILE([
		#include <time.h>
	], [
		timezone = 1;
	], ac_cv_var_timezone=yes, ac_cv_var_timezone=no))
if test $ac_cv_var_timezone = yes; then
	AC_DEFINE(HAVE_TIMEZONE, 1, [define if you have a timezone variable])
fi

dnl needed by libkmime
AC_CACHE_CHECK(for tm_gmtoff in struct tm, ac_cv_struct_tm_gmtoff,	
	AC_TRY_COMPILE([
		#include <time.h>
	], [
		struct tm tm;
		tm.tm_gmtoff = 1;
	], ac_cv_struct_tm_gmtoff=yes, ac_cv_struct_tm_gmtoff=no))
if test $ac_cv_struct_tm_gmtoff = yes; then
	AC_DEFINE(HAVE_TM_GMTOFF, 1, [Define if you have a tm_gmtoff member in struct tm])
fi

AC_LANG_PUSH(C++)
AC_CACHE_CHECK(for stl coping with namespace std, ac_cv_var_stlnamespace,
        AC_TRY_COMPILE([
                #include <iterator>
		struct s : public std::iterator<std::forward_iterator_tag, int> {};
        ], [
        ], ac_cv_var_stlnamespace=yes, ac_cv_var_stlnamespace=no))
if test $ac_cv_var_stlnamespace = yes; then
        AC_DEFINE(HAVE_STLNAMESPACE, 1, [Define if your version of stl is defined in namespace std])
	AC_DEFINE(STD_NAMESPACE_PREFIX, [std::], [Namespace prefix the stl is defined in])
else
	AC_DEFINE(STD_NAMESPACE_PREFIX, [], [Namespace prefix the stl is defined in])
fi

AC_LANG_POP