blob: bc0c0047439460f90eeda71897a2da71a202fbf0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
|
# Copyright 1999-2024 Gentoo Authors
# Copyright 2020-2025 The Trinity Desktop Project
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
TRINITY_NEED_ARTS="optional"
TRINITY_MODULE_NAME="tdeaddons"
TRINITY_MODULE_TYPE="core"
inherit trinity-meta-2 db-use multilib
DESCRIPTION="Various plugins for Noatun"
if [[ ${PV} != *9999* ]] ; then
KEYWORDS="~amd64 ~arm64 ~x86"
fi
IUSE="sdl berkdb"
COMMON_DEPEND="
~trinity-base/noatun-${PV}
berkdb? ( <sys-libs/db-6:=[cxx] )
"
DEPEND="${COMMON_DEPEND}
sdl? ( media-libs/libsdl )
"
RDEPEND="${COMMON_DEPEND}
sdl? ( media-libs/libsdl[X] )
"
src_configure() {
local mycmakeargs=(
-DWITH_SDL="$(usex sdl)"
-DWITH_BERKELEY_DB="$(usex berkdb)"
)
if use berkdb; then
# not using db_libname() because a full path to the library is required
local ver="$(db_findver "<sys-libs/db-6")"
[ -n "$ver" ] || die "No suitable sys-libs/db version found"
mycmakeargs+=(
-DBERKELEY_DB_LIBS="${ESYSROOT}/usr/$(get_libdir)/libdb_cxx-${ver}$(get_libname)"
-DBERKELEY_DB_INCLUDE_DIRS="${ESYSROOT}/usr/include/db${ver}"
)
fi
trinity-meta-2_src_configure
}
|
