Copy the KDE 3.5 branch to branches/trinity for new KDE 3.5 features.

BUG:215923


git-svn-id: svn://anonsvn.kde.org/home/kde/branches/trinity/kdelibs@1054174 283d02a7-25f6-0310-bc7c-ecb5cbfe19da

1 files changed, 106 insertions, 0 deletions

diff --git a/kdoctools/configure.in.in b/kdoctools/configure.in.in
new file mode 100644
index 000000000..2fcb7b75a
--- /dev/null
+++ b/kdoctools/configure.in.in
@@ -0,0 +1,106 @@
+
+# don't use it yet
+HELP_SUBDIR=kdoctools
+
+KDE_FIND_PATH(xml2-config, XML_CONFIG, [${prefix}/bin ${exec_prefix}/bin], [
+  AC_MSG_WARN([Could not find libxml2 anywhere, check ftp://xmlsoft.org/ for libxml >= 2.4.8. (we also keep a version of it in kdesupport for CVS users' convience)])
+  HELP_SUBDIR=
+])
+
+if test -n "$XML_CONFIG"; then
+  vers=`$XML_CONFIG --version 2>/dev/null | sed -e 's/libxml //' | awk 'BEGIN { FS = "."; } { printf "%d", ($1 * 1000 + $2) * 1000 + $3;}'`
+  if test -n "$vers" && test "$vers" -ge 2004008
+  then
+     LIBXML_LIBS="`$XML_CONFIG --libs`"
+     LIBXML_RPATH=
+     for args in $LIBXML_LIBS; do
+	  case $args in
+	    -L/usr/lib) ;;
+	    -L*)
+  	       LIBXML_RPATH="$LIBXML_RPATH $args"
+ 	       ;;
+          esac
+     done
+     LIBXML_RPATH=`echo $LIBXML_RPATH | sed -e "s/-L/-R/g"`
+     LIBXML_CFLAGS="`$XML_CONFIG --cflags`"
+
+     KDE_FIND_PATH(xmllint, XMLLINT, [${prefix}/bin ${exec_prefix}/bin], [XMLLINT=""])
+     AC_DEFINE_UNQUOTED(XMLLINT, "$XMLLINT", [Defines the executable of xmllint])
+  else
+     AC_MSG_WARN([You need at least libxml 2.4.8])
+     HELP_SUBDIR=
+  fi
+fi
+
+if test -n "$HELP_SUBDIR"; then
+
+  KDE_FIND_PATH(xslt-config, XSLT_CONFIG, [${prefix}/bin ${exec_prefix}/bin], [
+    AC_MSG_WARN([Could not find libxslt anywhere, check ftp://xmlsoft.org/ for libxslt >= 1.0.7. (we also keep a version of it in kdesupport for CVS users' convience)])
+    HELP_SUBDIR=
+  ])
+
+  if test -n "$XSLT_CONFIG"; then
+     vers=`$XSLT_CONFIG --version 2>/dev/null | awk 'BEGIN { FS = "."; } { printf "%d", ($1 * 1000 + $2) * 1000 + $3;}'`
+     if test -n "$vers" && test "$vers" -ge 1000007; then
+       LIBXSLT_LIBS="`$XSLT_CONFIG --libs`"
+       LIBXSLT_RPATH=
+       for args in $LIBXSLT_LIBS; do
+	  case $args in
+	    -L/usr/lib) ;;
+	    -L*)
+  	       LIBXSLT_RPATH="$LIBXSLT_RPATH $args"
+ 	       ;;
+          esac
+       done
+       LIBXSLT_RPATH=`echo $LIBXSLT_RPATH | sed -e "s/-L/-R/g"`
+       LIBXSLT_CFLAGS="`$XSLT_CONFIG --cflags`"
+
+     else
+       AC_MSG_WARN([You need at least libxslt 1.0.7])
+       HELP_SUBDIR=
+     fi
+  fi
+fi
+
+AC_DEFUN([KDOCTOOLS_CHECK_BZIP2],
+[
+AC_REQUIRE([AC_FIND_BZIP2])
+AC_MSG_CHECKING([for present bzip2 support])
+if test -z "$LIBBZ2"; then
+	AC_MSG_RESULT([no - disabling doc compiler])
+	HELP_SUBDIR=
+else
+	AC_MSG_RESULT([ok])
+fi
+])
+KDOCTOOLS_CHECK_BZIP2
+
+if test -n "$HELP_SUBDIR"; then  
+  MEINPROC='$(top_builddir)/kdoctools/meinproc --srcdir=$(top_srcdir)/kdoctools'
+  MEINPROC_DEP='$(top_builddir)/kdoctools/meinproc'
+  KDE_XSL_STYLESHEET='$(top_srcdir)/kdoctools/customization/kde-chunk.xsl'
+else
+  MEINPROC=""
+  MEINPROC_DEP=""
+  KDE_XSL_STYLESHEET=""
+  DO_NOT_COMPILE="$DO_NOT_COMPILE kdoctools"
+fi
+
+if test ! "$USE_RPATH" = "yes"; then
+  LIBXSLT_RPATH=
+  LIBXML_RPATH=
+fi
+
+AC_SUBST(LIBXSLT_LIBS)
+AC_SUBST(LIBXSLT_CFLAGS)
+AC_SUBST(LIBXSLT_RPATH)
+
+AC_SUBST(LIBXML_LIBS)
+AC_SUBST(LIBXML_CFLAGS)
+AC_SUBST(LIBXML_RPATH)
+AC_SUBST(HELP_SUBDIR)
+AC_SUBST(MEINPROC) 
+AC_SUBST(MEINPROC_DEP)
+AC_SUBST(KDE_XSL_STYLESHEET)
+
+dnl AC_OUTPUT(kdoctools/checkXML)